This site uses cookies for analytics, personalized content and ads. By continuing to browse this site, you agree to this use.
Author Image Tuesday, 16 May 2017

[BatchScript] Hướng dẫn gỡ bỏ Microsoft Edge trên Windows 10


Chào các bạn, ở một số bài viết trước tôi có giới thiệu đến kỹ thuật gỡ bỏ 1 số thành phần trong sources cài ISO như Windows Defender, OneDrive... về  bản chất các command áp dụng cho bộ cài iso - dism /image.... đều có thể dùng để chạy trực tiếp trên windows khi chuyển /image thành /online

Ok giờ ta bắt đầu !

Cách 1 : làm thủ công

Mở RUN và gõ vào từ khóa regedit

Tiếp theo bạn truy cập
Computer\HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Appx\AppxAllUserStore\InboxApplications
Tìm tới khóa chứa tên Edge chuột phải và xóa nó đi


Lưu ý: nếu như windows từ chối cho xóa bạn cần cấp quyền điều khiển cho khóa đó bằng cách chuột phải vào khóa đó chọn Permissions và cấp full quyền control cho tài khoản user bạn đang sử dụng

Tiếp theo bạn truy cập vào
Computer\HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Component Based Servicing\Packages

Tìm tới khóa có tên Microsoft-Windows-Internet-Browser-Package...

Trong nó có key con là Owner bạn tiến hành xóa từng key con đó đi

Tiếp theo mở cmd với quyền admin và dán lệnh sau để gỡ bỏ
dism /online /remove-package /packagename:Microsoft-Windows-Internet-Browser-Package~31bf3856ad364e35~amd64~en-US~10.0.16193.1001
dism /online /remove-package /packagename:Microsoft-Windows-Internet-Browser-Package~31bf3856ad364e35~amd64~~10.0.16193.1001

Trong đó packagename bạn lấy nhanh bằng cách chuột phải vào tên khóa trong registry chọn Rename và copy ra. Nếu yêu cầu khởi động lại bạn chọn N

Cuối cùng ta sẽ xóa thư mục của Edge trong C:\Windows\SystemApps

Tương tự để xóa 1 thư mục hệ thống bạn cần lấy quyền quản trị bằng Take owner ship nhé.

Sau khi hoàn tất bạn tiến hành khởi động lại máy tính để tận hưởng thành quả

Cách 2: sử dụng BatchScript

Trước tiên để sử dụng phương pháp này bạn cần chiếm được quyền điều khiển của khóa sau
Computer\HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Appx\AppxAllUserStore\InboxApplications

Computer\HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Component Based Servicing\Packages
Cách cấp quyền như sau: chuột phải vào khóa và chọn Permissions...→ Advanced → Change → Tại ô text bạn điền tên user của mình vào sau đó chọn Check Name, nếu như đúng hệ thống sẽ tự thiết lập đúng cho tên user → OK

Thay thế quyền sở hữu

Và cuối cùng là cấp full control cho các tài khoản user và admin

Tạo 1 file .bat có nội dung như sau và chạy

:: Made by Hoang Hung
@echo off
color 0f
mode con: cols=140 lines=30
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
if "%errorlevel%" NEQ "0" (
 echo: Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
 echo: UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
 "%temp%\getadmin.vbs" & exit 
)
if exist "%temp%\getadmin.vbs" del /f /q "%temp%\getadmin.vbs"
 
Title Remove Microsoft Edge
 
for /f "tokens=2*" %%e in ('reg query "HKEY_CLASSES_ROOT\CLSID\{5FDD51E2-A9D0-44CE-8C8D-162BA0C591A0}" /v "Version"') do set vers=%%f
 
if %PROCESSOR_ARCHITECTURE% EQU AMD64 (set arc=amd64) else (set arc=x86)
 
echo.
echo Deleting key in "Computer\HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Appx\AppxAllUserStore\InboxApplications"
 
for /f "tokens=1" %%a in ('reg query "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Appx\AppxAllUserStore\InboxApplications" ^| find /i "Microsoft.MicrosoftEdge"') do (set pack=%%a)
for /f "tokens=9 delims=\" %%b in ("%pack%") do (set packagename=%%b)
if "%packagename%" == "" ( echo.&echo Key doesn't exist...
) else (
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Appx\AppxAllUserStore\InboxApplications\%packagename%" /f
)
 
set packowner=(Microsoft-Windows-Internet-Browser-Package~31bf3856ad364e35~%arc%~~%vers%)
 
for /d %%b in %packowner% do (
echo ========================================================================
echo Deleting key in "Computer\HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Component Based Servicing\Packages\%%b\Owners"
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Component Based Servicing\Packages\%%b\Owners" /f
echo ========================================================================
echo Removing package %%b...
dism /online /remove-package /packagename:%%b /NoRestart
)
echo ========================================================================
pause

Chức năng của file này sẽ xóa đi các khóa cần thiết liên quan tới Microsoft Edge sau đó sẽ gỡ các gói bằng tùy chọn /remove-package.

LƯU Ý: Nếu trong quá trình chạy bạn thấy xuất hiện thông báo tương tự như này
thì đừng lo nhé, nó báo gói package đó không có trong phiên bản windows bạn sử dụng thôi !

Sau khi script chạy xong bạn tiến hành khởi động lại máy tính để tận hưởng thành quả

Chúc thành công
Comments:
Bạn được tự do bày tỏ quan điểm nhưng nghiêm cấm spam
  • Chèn ảnh theo mẫu [img]link[/img]
  • Chèn video Youtube theo mẫu [youtube]link[/youtube]
  • Chèn code theo mẫu [pre]code[/pre]. Lưu ý: mã hóa code trước khi bình luận

  • Please wait while i am loading Facebook SDK js