Labels

[BatchScript] Hướng dẫn gỡ bỏ Windows Mixed Reality trên Windows 10


Đây là một ứng dụng khá mới, nó bắt đầu xuất hiện từ phiên bản Windows 10 RS2 trên bản 64-Bit. Nếu bạn chưa biết nó là gì thì có thể tìm hiểu nó tại đây . Và nếu như không có nhu cầu dùng như tôi thì có thể gỡ nó trực tiếp trên hệ điều hành đang sử dụng bằng dism /online

Tên gói cài đặt của nó là Microsoft-Windows-Holographic.. và nếu như bạn muốn làm thủ công có thể tham khảo cách làm tương tự như bài viết HƯỚNG DẪN GỠ BỎ MICROSOFT EDGE TRÊN WINDOWS 10. Ở bài này tôi sẽ thu gọn các thao tác hơn bằng việc dùng file batch.

Trước tiên để sử dụng phương pháp này bạn cần chiếm được quyền điều khiển của khóa sau
Computer\HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Appx\AppxAllUserStore\InboxApplications

Computer\HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Component Based Servicing\Packages
Cách cấp quyền như sau: chuột phải vào khóa và chọn Permissions...→ Advanced → Change → Tại ô text bạn điền tên user của mình vào sau đó chọn Check Name, nếu như đúng hệ thống sẽ tự thiết lập đúng cho tên user → OK

Thay thế quyền sở hữu

Và cuối cùng là cấp full control cho các tài khoản user và admin

Tạo 1 file .bat. Tham khảo bài viết THÊM "NEW SCRIPT FILE" VÀO CONTEXT MENU CHUỘT PHẢI.

Tiếp theo bạn copy toàn bộ nội dung sau và dán vào sau đó lưu lại

:: Made by Hoang Hung
@echo off
 
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
if "%errorlevel%" NEQ "0" (
 echo: Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
 echo: UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
 "%temp%\getadmin.vbs" & exit 
)
if exist "%temp%\getadmin.vbs" del /f /q "%temp%\getadmin.vbs"
 
Title Remove Windows Mixed Reality
 
for /f "tokens=2*" %%e in ('reg query "HKEY_CLASSES_ROOT\CLSID\{5FDD51E2-A9D0-44CE-8C8D-162BA0C591A0}" /v "Version"') do set vers=%%f
 
echo.&echo Deleting key in "Computer\HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Appx\AppxAllUserStore\InboxApplications"
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Appx\AppxAllUserStore\InboxApplications\Microsoft.Windows.HolographicFirstRun_%vers%_neutral_neutral_cw5n1h2txyewy" /f
 
set pack=(Microsoft-Windows-Holographic-Desktop-Analog-Package~31bf3856ad364e35~amd64~~%vers%,Microsoft-Windows-Holographic-Desktop-Merged-analog-Package~31bf3856ad364e35~amd64~~%vers%,Microsoft-Windows-Holographic-Desktop-Merged-onecoreuap-Package~31bf3856ad364e35~amd64~~%vers%,Microsoft-Windows-Holographic-Desktop-Merged-Package~31bf3856ad364e35~amd64~~%vers%,Microsoft-Windows-Holographic-Desktop-Merged-pcshell-Package~31bf3856ad364e35~amd64~~%vers%,Microsoft-Windows-Holographic-Desktop-Merged-shellcommon-Package~31bf3856ad364e35~amd64~~%vers%,Microsoft-Windows-Holographic-Desktop-Merged-windows-Package~31bf3856ad364e35~amd64~~%vers%,Microsoft-Windows-Holographic-Desktop-Merged-WOW64-analog-Package~31bf3856ad364e35~amd64~~%vers%,Microsoft-Windows-Holographic-Desktop-Merged-WOW64-Package~31bf3856ad364e35~amd64~~%vers%,Microsoft-Windows-Holographic-Desktop-Merged-WOW64-shellcommon-Package~31bf3856ad364e35~amd64~~%vers%)
 
for /d %%b in %pack% do (
echo ========================================================================================
echo Deleting key in "Computer\HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Component Based Servicing\Packages\%%b\Owners"
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Component Based Servicing\Packages\%%b\Owners" /f
echo.
)
set packremove=(Microsoft-Windows-Holographic-Desktop-Analog-Package~31bf3856ad364e35~amd64~~%vers%,Microsoft-Windows-Holographic-Desktop-Merged-analog-Package~31bf3856ad364e35~amd64~~%vers%,Microsoft-Windows-Holographic-Desktop-Merged-onecoreuap-Package~31bf3856ad364e35~amd64~~%vers%,Microsoft-Windows-Holographic-Desktop-Merged-Package~31bf3856ad364e35~amd64~~%vers%,Microsoft-Windows-Holographic-Desktop-Merged-WOW64-analog-Package~31bf3856ad364e35~amd64~~%vers%,Microsoft-Windows-Holographic-Desktop-Merged-WOW64-Package~31bf3856ad364e35~amd64~~%vers%)
 
for /d %%c in %packremove% do (
echo ========================================================================================
echo Removing package %%c...
dism /online /remove-package /packagename:%%c /NoRestart
echo.
)
echo ========================================================================================
pause

Chức năng của file này sẽ xóa đi các khóa cần thiết liên quan tới Windows Mixed Reality sau đó sẽ gỡ các gói bằng tùy chọn /remove-package.

LƯU Ý: Nếu trong quá trình chạy bạn thấy xuất hiện thông báo tương tự như này
thì đừng lo nhé, nó báo gói package đó không có trong phiên bản windows bạn sử dụng thôi !

Sau khi file batch chạy xong bạn làm bước cuối là xóa thư mục chứa gói của Windows Mixed Reality trong ổ C:\Windows\SystemApps . Và đương nhiên bạn cũng cần phải có Take owner ship để xóa nó.

Cuối cùng là khởi động lại máy tính để tận hưởng thành quả

Good Luck !