This site uses cookies for analytics, personalized content and ads. By continuing to browse this site, you agree to this use.
Author Image Sunday, 21 May 2017

[BatchScript] Hướng dẫn gỡ bỏ vĩnh viễn Internet Explorer trên Windows 10


Internet Explorer chắc đã quá quen thuộc với người dùng Windows rồi, với Windows 10 hiện nay Microsoft tập trung phát triển Edge nhiểu hơn là IE cộng với Chrome, Firefox đang khẳng định vị thế nên dường như đồng chí này chỉ còn được sử dụng để...tải Chrome, Firefox :). Và nếu như bạn muốn gỡ bỏ nó thì hãy tham khảo bài viết dưới đây


Cách 1: Làm thủ công

Tên gói của nó là Microsoft-Windows-InternetExplorer... bạn tham khảo bài viết [BATCHSCRIPT] HƯỚNG DẪN GỠ BỎ MICROSOFT EDGE TRÊN WINDOWS 10. Tuy nhiên bạn chỉ cần thao tác với 2 gói sau
  • Microsoft-Windows-InternetExplorer-Optional-Package~31bf3856ad364e35~x86~~11.0.15063.0 
  • Microsoft-Windows-InternetExplorer-Package~31bf3856ad364e35~x86~~11.0.15063.0
Phần in đậm sẽ không đổi trên các version của Windows 10

Cách 2: Sử dụng BatchScript

Trước tiên để sử dụng phương pháp này bạn cần chiếm được quyền điều khiển của khóa sau
Computer\HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Component Based Servicing\Packages

Cách cấp quyền như sau: chuột phải vào khóa và chọn Permissions...→ Advanced → Change → Tại ô text bạn điền tên user của mình vào sau đó chọn Check Name, nếu như đúng hệ thống sẽ tự thiết lập đúng cho tên user → OK


Thay thế quyền sở hữu


Và cuối cùng là cấp full control cho các tài khoản user và admin


Tạo 1 file .bat. Tham khảo bài viết THÊM "NEW SCRIPT FILE" VÀO CONTEXT MENU CHUỘT PHẢI.

Tiếp theo bạn copy toàn bộ nội dung sau và dán vào sau đó lưu lại

@echo off
 
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
if "%errorlevel%" NEQ "0" (
 echo: Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
 echo: UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
 "%temp%\getadmin.vbs" & exit 
)
if exist "%temp%\getadmin.vbs" del /f /q "%temp%\getadmin.vbs"
 
title Remove Internet Explorer
 
if %PROCESSOR_ARCHITECTURE% EQU AMD64 (set arch=amd64) else (set arch=x86)
 
for /f "tokens=10 delims=\ " %%a in ('reg query "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Component Based Servicing\Packages" ^| find /i "Microsoft-Windows-InternetExplorer-Package~31bf3856ad364e35~%arch%~~"') do (set pack=%%a)
for /f "tokens=7-10 delims=-~." %%b in ("%pack%") do (set vers=%%b.%%c.%%d.%%e)
 
set packremove=(Microsoft-Windows-InternetExplorer-Package~31bf3856ad364e35~%arch%~~%vers%,Microsoft-Windows-InternetExplorer-Optional-Package~31bf3856ad364e35~%arch%~~%vers%)
 
for /d %%b in %packremove% do (
echo ========================================================================
echo Deleting key in "Computer\HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Component Based Servicing\Packages\%%b\Owners"
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Component Based Servicing\Packages\%%b\Owners" /f
echo.
echo ========================================================================
echo Removing package %%b...
dism /online /remove-package /packagename:%%b /NoRestart
)
echo ========================================================================
pause

Chức năng của file này sẽ xóa đi các khóa cần thiết liên quan tới Internet Explorer sau đó sẽ gỡ các gói bằng tùy chọn /remove-package.

LƯU Ý: Nếu trong quá trình chạy bạn thấy xuất hiện thông báo tương tự như này


thì đừng lo nhé, nó báo gói package đó không có trong phiên bản windows bạn sử dụng thôi !

Sau khi script chạy xong bạn tiến hành khởi động lại máy tính, bạn có thể kiểm tra nhanh xem đã gỡ hoàn chưa bằng việc truy cập C:\Program Files\Internet Explorer hoặc C:\Program Files (x86)\Internet Explorer

Good Luck !
Comments:
Bạn được tự do bày tỏ quan điểm nhưng nghiêm cấm spam
  • Chèn ảnh theo mẫu [img]link[/img]
  • Chèn video Youtube theo mẫu [youtube]link[/youtube]
  • Chèn code theo mẫu [pre]code[/pre]. Lưu ý: mã hóa code trước khi bình luận

  • Please wait while i am loading Facebook SDK js