Labels

[BatchScript] Hướng dẫn gỡ bỏ vĩnh viễn Cortana trên Windows 10


Cortana là một điểm nhấn rõ rệt của Windows 10, cô trợ lý ảo này giúp ta khá nhiều việc, tuy nhiên vẫn có khá nhiều người muốn tìm cách gỡ bỏ nó 1 phần vì nó có tiến trình chạy ngầm, 1 phần ...vì họ muốn xóa :))

Chớ chêu thay Cortana và Search lại luôn đi cùng với nhau đồng nghĩa với việc gỡ cortana sẽ chia tay luôn thanh search. Và nếu như bạn đã quyết định sẽ gỡ nó hãy tham khảo bài viết dưới đây, bạn có thể dùng công cụ thay thế search, tham khảo bài viết [SOFT] STARTISBACK REPACK CẬP NHẬT THƯỜNG XUYÊN

Trước tiên để sử dụng phương pháp này bạn cần chiếm được quyền điều khiển của khóa sau
Computer\HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Appx\AppxAllUserStore\InboxApplications

Computer\HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Component Based Servicing\Packages
Cách cấp quyền như sau: chuột phải vào khóa và chọn Permissions...→ Advanced → Change → Tại ô text bạn điền tên user của mình vào sau đó chọn Check Name, nếu như đúng hệ thống sẽ tự thiết lập đúng cho tên user → OK

Thay thế quyền sở hữu

Và cuối cùng là cấp full control cho các tài khoản user và admin

Tạo 1 file .bat. Tham khảo bài viết THÊM "NEW SCRIPT FILE" VÀO CONTEXT MENU CHUỘT PHẢI.

Tiếp theo bạn copy toàn bộ nội dung sau và dán vào sau đó lưu lại

:: Made by Hoang Hung
@echo off
 
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
if "%errorlevel%" NEQ "0" (
 echo: Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
 echo: UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
 "%temp%\getadmin.vbs" & exit 
)
if exist "%temp%\getadmin.vbs" del /f /q "%temp%\getadmin.vbs"
 
Title Remove Cortana ^& Search
 
for /f "tokens=2*" %%e in ('reg query "HKEY_CLASSES_ROOT\CLSID\{5FDD51E2-A9D0-44CE-8C8D-162BA0C591A0}" /v "Version"') do set vers=%%f
 
if %PROCESSOR_ARCHITECTURE% EQU AMD64 (set arc=amd64) else (set arc=x86)
 
echo.
echo Deleting key in "Computer\HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Appx\AppxAllUserStore\InboxApplications"
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Appx\AppxAllUserStore\InboxApplications\Microsoft.Windows.Cortana_%vers%_neutral_neutral_cw5n1h2txyewy" /f
 
set pack=(Microsoft-Windows-Cortana-Package~31bf3856ad364e35~%arc%~~%vers%,Microsoft-Windows-Cortana-PAL-Desktop-Package~31bf3856ad364e35~%arc%~~%vers%)
 
for /d %%b in %pack% do (
echo ========================================================================
echo Deleting key in "Computer\HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Component Based Servicing\Packages\%%b\Owners"
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Component Based Servicing\Packages\%%b\Owners" /f
echo.
)
set packremove=(Microsoft-Windows-Cortana-Package~31bf3856ad364e35~%arc%~~%vers%,Microsoft-Windows-Cortana-PAL-Desktop-Package~31bf3856ad364e35~%arc%~~%vers%)
 
for /d %%c in %packremove% do (
echo ========================================================================
echo Removing package %%c...
dism /online /remove-package /packagename:%%c /NoRestart
echo.
)
reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Search" /v SearchboxTaskbarMode /t REG_DWORD /d 0 /f
taskkill /IM explorer.exe /F >nul 2>&1
explorer.exe >nul 2>&1
echo ========================================================================
pause

Chức năng của file này sẽ xóa đi các khóa cần thiết liên quan tới Cortana sau đó sẽ gỡ các gói bằng tùy chọn /remove-package.

LƯU Ý: Nếu trong quá trình chạy bạn thấy xuất hiện thông báo tương tự như này
thì đừng lo nhé, nó báo gói package đó không có trong phiên bản windows bạn sử dụng thôi !

Sau khi script chạy xong bạn tiến hành khởi động lại máy tính để tận hưởng thành quả


Good Luck !